StonQL Reference

What is StonQL?

StonQL (pronounced "Stonk-QL") is a domain-specific language for filtering stocks based on price, volume, and technical indicators.

A basic scan:

close > 50;

This returns all stocks with a closing price above $50.

A more practical example:

close > sma(close, 50);

This returns stocks trading above their 50-day simple moving average.

Statements

A statement is a single condition that must be true for a stock to appear in your results. Every statement ends with a semicolon.

volume > 1M;

This statement filters for stocks with volume greater than 1 million shares.

Comments

Add notes to your scans using comments. Comments are ignored when the scan runs.

// Single-line comment
volume > 1M; // Comment at end of line

/* Multi-line comment
   spanning multiple lines */
close > open;

Combining Statements

When you write multiple statements, a stock must satisfy all of them to appear in results. Think of it as "AND" logic.

close > 10;           // Price above $10
close < 50;           // Price below $50
volume > 500K;        // Volume above 500,000

This scan returns only stocks where all three conditions are true: price between $10-$50 with decent volume.

Need "OR" logic? Use the or operator within a single statement:

rsi(close, 14) < 30 or rsi(close, 14) > 70;

This finds stocks that are either oversold (RSI below 30) or overbought (RSI above 70).

Fields

Fields are the data points you use in your scans. They represent price, volume, and other stock information.

close > 100;

close > open;

high > high[1];

low > high[1];

volume > 1M;

close > typical_price;

sma(ohlc4, 20);

months_since(first_trade_date) < 6;

Variables

Use variables to name your calculations. This makes complex scans easier to read and lets you reuse values.

avg_vol = sma(volume, 20);
volume > avg_vol * 2;  // Volume is 2x the 20-day average

Variables are especially helpful when you need the same calculation multiple times:

ma50 = sma(close, 50);
ma200 = sma(close, 200);
close > ma50;      // Price above 50-day MA
ma50 > ma200;      // 50-day MA above 200-day MA (bullish alignment)

Number Formats

StonQL supports several number formats for convenience:

Operators

Comparison Operators

Logical Operators

Arithmetic Operators

Historical Reference

Access values from previous periods. The number in brackets indicates how many periods back.

Multi-Timeframe Analysis

Use mtf() blocks to combine conditions across multiple timeframes in a single scan. Filter stocks that meet criteria on daily, weekly, and monthly charts simultaneously.

Filter Mode

When a mtf() block contains boolean conditions, stocks must pass all conditions in that timeframe to appear in results.

// Daily scan with weekly and monthly filters
close > sma(close, 20);        // Daily: above 20-day MA

mtf("1W") {
    close > open;              // Weekly: green candle
    rsi(close, 14) > 50;       // Weekly: bullish momentum
}

mtf("1M") {
    close > sma(close, 3);     // Monthly: uptrend
}

Stocks must pass daily conditions AND weekly conditions AND monthly conditions.

Value Extraction Mode

Assign a mtf() block to a variable to extract values from another timeframe for use in comparisons.

// Extract previous week's high for breakout detection
prev_weekly_high = mtf("1W") { high[1]; };

// Daily breakout above last week's high
close > prev_weekly_high;
volume > sma(volume, 20) * 1.5;

The [1] gets the previous week's value, avoiding same-bar comparisons.

Scope Isolation

mtf() blocks are completely isolated. Variables defined outside cannot be used inside, and vice versa.

// CORRECT: Self-contained mtf() block
mtf("1W") {
    avg = sma(close, 20);      // 'avg' only exists inside this block
    close > avg;
}

// CORRECT: Value extraction creates outer variable
weekly_rsi = mtf("1W") { rsi(close, 14); };
rsi(close, 14) > weekly_rsi;   // Compare daily RSI to weekly RSI

// WRONG: Cannot reference outer variables in mtf() blocks
threshold = 50;
mtf("1W") { rsi(close, 14) > threshold; };  // ERROR!

// VALID: Check if today made the monthly high (equality)
monthly_high = mtf("1M") { high; };
high == monthly_high;          // Valid: detecting monthly high bar

// WRONG: Inequality comparison to containing period
monthly_high = mtf("1M") { high; };
high > monthly_high;           // NEVER true - daily high can't exceed monthly high it's part of!

// CORRECT: Use [1] for inequality comparisons
prev_monthly_high = mtf("1M") { high[1]; };
close > prev_monthly_high;     // Meaningful: breaking above last month's high

The rule: Equality checks (==, ~=) against current period values are valid for detecting extremes. Inequality checks (>, <) are faulty because the daily value is part of the aggregate. Use [1] for inequality comparisons.

Combining Indicators Across Timeframes

// Multi-timeframe momentum alignment
prev_weekly_rsi = mtf("1W") { rsi(close, 14)[1]; };
prev_monthly_rsi = mtf("1M") { rsi(close, 14)[1]; };

// Daily RSI stronger than both higher timeframes
rsi(close, 14) > prev_weekly_rsi;
rsi(close, 14) > prev_monthly_rsi;
rsi(close, 14) > 50;           // And above neutral

Functions

Click on any function to view detailed documentation with parameters, formulas, and examples.

Quick Index (A-Z)

abs() · all_time_high() · all_time_low() · and() · approx() · aroon_down() · aroon_osc() · aroon_up() · atr() · bb_lower() · bb_upper() · bb_width() · cci() · change() · count() · cross() · crossover() · crossunder() · days_since() · dev() · ema() · eq() · falling() · gt() · gte() · highest() · highest_bars_ago() · hma() · kc_lower() · kc_middle() · kc_upper() · kcw() · lowest() · lowest_bars_ago() · lt() · lte() · macd_histogram() · macd_line() · macd_signal() · max() · mean() · median() · mfi() · min() · mom() · months_since() · ne() · obv() · or() · pct_change() · percentrank() · pivothigh() · pivotlow() · pow() · range() · rising() · roc() · rsi() · sma() · sqrt() · stdev() · stoch_d() · stoch_k() · streak() · swma() · true_range() · variance() · vwma() · weeks_since() · wilderma() · williams_r() · wma() · years_since()